@BEGINEVENTS

@IF
NOSCHISM
defender=ANYBODY
@THEN
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=31
receiver=Neutrals
@THEN
TEXT
^
The Neutrals have experimented with Borg Technology and
their empire has been laid to waste in the aftermath.
^
ENDTEXT
DESTROYACIVILIZATION
whom=TRIGGERRECEIVER
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=31
receiver=Romulans
@THEN
TEXT
^
The Romulans have experimented with Borg Technology and
their empire has been laid to waste in the aftermath.
^
ENDTEXT
DESTROYACIVILIZATION
whom=TRIGGERRECEIVER
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=31
receiver=Federation
@THEN
TEXT
^
The Federation has experimented with Borg Technology and
their empire has been laid to waste in the aftermath.
^
ENDTEXT
DESTROYACIVILIZATION
whom=TRIGGERRECEIVER
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=31
receiver=Klingons
@THEN
TEXT
^
The Klingons have experimented with Borg Technology and
their empire has been laid to waste in the aftermath.
^
ENDTEXT
DESTROYACIVILIZATION
whom=TRIGGERRECEIVER
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=31
receiver=Orions
@THEN
TEXT
^
The Orions have experimented with Borg Technology and
their empire has been laid to waste in the aftermath.
^
ENDTEXT
DESTROYACIVILIZATION
whom=TRIGGERRECEIVER
@ENDIF

@IF
NEGOTIATION
talker=Federation
talkertype=HumanOrComputer
listener=Borg
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Klingons
talkertype=HumanOrComputer
listener=Borg
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
NEGOTIATION
talker=Romulans
talkertype=HumanOrComputer
listener=Borg
listenertype=HumanOrComputer
@THEN
@ENDIF

@IF
TURN
turn=-1
@THEN
MAKEAGGRESSION
who=Borg
whom=Federation
@ENDIF

@IF
TURN
turn=-1
@THEN
MAKEAGGRESSION
who=Borg
whom=Klingons
@ENDIF

@IF
TURN
turn=-1
@THEN
MAKEAGGRESSION
who=Borg
whom=Romulans
@ENDIF

@IF
TURN
turn=50
@THEN
PLAYWAVEFILE
EXTRA8.WAV
@ENDIF

@IF
TURN
turn=1
@THEN
CHANGETERRAIN
terraintype=1
maprect
44,10,44,10,44,10,44,10
@ENDIF

@IF
TURN
turn=-1
@THEN
CREATEUNIT
unit=Ion Storm
owner=borg
veteran=yes
homecity=none
locations
44,10
endlocations
@ENDIF

@IF
TURN
turn=1
@THEN
TEXT
^   PROLOGUE - A New Dawn
^^
^^  It is the year 2200, the dawn of the 23rd Century. The younger races are
^^  finally close to achieving space flight and so the saga begins....
^
^^  As leader of your species, research technologies, grow your empire, seek
^^  out new lifeforms and new civilisations. Boldly prepare for the challenges
^^  that are to come. Currently, travelling on impulse power limits your
^^  reach to the planets of two nearby solar systems. You must research warp
^^  drive and a freighter design before you can expand further.
^
ENDTEXT
@ENDIF

@IF
TURN
turn=10
@THEN
TEXT
^   CHAPTER ONE - Rumours Travel Faster than Warp 10
^^
^^  Traders and explorers from faraway worlds bring rumours of a race
^^  of technologically advanced cybernetic beings from the Delta
^^  Quadrant, one that is sweeping through all that stand in its way.
^
^^  Even at Warp Factor 9 (1516 x speed of light or 1 trillion m.p.h),
^^  it would take 70 years to travel to or from the Delta Quadrant. Even
^^  so, we should quicky expand our domain so that we will be able to
^^  resist these beings when they eventually arrive at our borders.
^
ENDTEXT
@ENDIF

@IF
TURN
turn=50
@THEN
TEXT
CHAPTER TWO - The Dreaded Day
^
^^ A Vulcan science vessel, the V.S.S. VODANBE'REY, on a deep space survey
^^ mission disappears. Eventually, a log bouy that was jettisoned is recovered.
^^ Although the bouy was badly damaged, a part of the V.S.S. VODANBE'REY
^^ audio log was reconstructed and made available to all.
^
^^ Eventually, your agents manage to get their hands on this recording....
^^ It seems that the BORG can exceed Warp Nine!
^
ENDTEXT
PLAYWAVEFILE
EXTRA6.WAV
@ENDIF

@IF
TURN
turn=105
@THEN
TEXT
CHAPTER THREE - Legacy of our Days Gone By
^
^^ Long range surveys have revealed a planet which may be of cultural or
^^ strategic importance to our species. Currently we do not know how
^^ capturing the planet will help in our campaign for dominance in the
^^ quadrant. However, we should plan to capture this planet sometime in
^^ the future when we have the military resources.
^
^For the Federation, this planet is Bolia
^For the Romulans, this planet is Vulcan
^For the Klingons, this planet is Tellar
^
ENDTEXT
@ENDIF

@IF
CITYTAKEN
city=Vulcan
attacker=Romulans
defender=ANYBODY
@THEN
TEXT
^
BONUS CHAPTER - Forced Reunification
^
^^ It is now revealed to all that Romulans were originally Vulcans who left their
^^ home planet in space arks during the 'Sundering'. This was due to their opposition
^^ to Surak's 'Reformation Movement' which displaced the warrior ethic with mental
^^ development. Thus the Romulans never learned the Mind Rules.
^
^^ The capture of Vulcan by the Romulans leads to the long awaited Reunification.
^^ The Romulans now regain the long lost Mind Rules and with the fusion of the
^^ warrior ethic and their newfound mental powers are able to field a new type of
^^ unit known as Telepaths. Telepaths are ground units whose defensive capability
^^ exceeds even those of the advanced positronic SDF battalions.
^
ENDTEXT
JUSTONCE
GIVETECHNOLOGY
receiver=Romulans
technology=19
@ENDIF

@IF
CITYTAKEN
city=Bolia
attacker=Federation
defender=ANYBODY
@THEN
TEXT
BONUS CHAPTER - Present Tense, Past Tense
^
^^ After the Federation capture of Bolia, a message pod from Commander Will
^^ Decker who had merged with the V'Ger entity, is found in orbit. The contents of the
^^ message, encrypted for Federation use only, are as follows:
^
^^ James, I have discovered that the world of machines which transformed Voyager VI
^^ into V'Ger is populated by a species known as the BORG. They plan to invade the
^^ Alpha Quadrant sometime soon based on the information that V'Ger relayed to them
^^ before our evolution. Any help which I can offer from where Ilia and I are now is
^^ limited. I entrust to you blueprints of an advanced escourt class starship......
^
^^ The Federation builds one prototype, NX-74205 U.S.S. Defiant. This nimble starship
^^ is able to operate in both the atmoshpere and in open space but has limited range.
^
ENDTEXT
CREATEUNIT
unit=Defiant
owner=Federation
veteran=yes
homecity=none
locations
102,96
102,98
102,100
104,96
104,98
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=Tellar
attacker=Klingons
defender=ANYBODY
@THEN
TEXT
BONUS CHAPTER - A Symbol to Rally Around
^
^^ The Hur'q were once the ruthless dominant species in the quadrant and on one
^^ expedition, they plundered the revered object, the Sword of Kahless, from the
^^ Klingon Homeworld (Kahless and his wife Lukara were the legendary founders of
^^ the Klingon race). The Hur'q have long since become extinct but the sword
^^ (actually a bat'leth) was never recovered.
^
^^ Klingon Scientists discover a Hur'q archaeological site which has been burried
^^ in a moon of Tellar for over a millenium. Within a vault, the Sword of Kahless
^^ is recovered. Klingons receive the unit Kahless' Sword but only if they still
^^ control Qo'Nos (practically nothing short of a Genesis Torpedo can kill it).
^
ENDTEXT
CREATEUNIT
unit=Kahless' Sword
owner=Klingons
veteran=yes
homecity=Qo'nos
locations
5,75
endlocations
JUSTONCE
@ENDIF

@IF
UNITKILLED
unit=Sphere
attacker=ANYBODY
defender=Borg
@THEN
TEXT
CHAPTER FOUR - the Matter of the BORG Sphere
^
^^ A BORG sphere has been destroyed. This proves that the BORG are not invincible
^^ after all. A magnetic container was found in the twisted wreckage after the sphere
^^ self-destructed to avoid caputre. A substance know as proto-matter was discovered
^^ within the container.....(ATTACKER DISCOVERS PROTO-MATTER)
^
^^ Proto-matter is a dangerous and highly unstable form of matter which is avoided
^^ by any ethical scientist. However, as our expansion is limited by the other races
^^ around us, we may have no choice but to use proto-matter to design a Genesis Device.
^^ The device will allow us to create new hospitable planets for colonisation. If so,
^^ we will also need to build deep space labs for safe testing before we can field a
^^ working prototype.
^
ENDTEXT
JUSTONCE
GIVETECHNOLOGY
receiver=TRIGGERATTACKER
technology=25
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=46
receiver=Orions
@THEN
TEXT
CHAPTER FIVE - the Secret of the Orions
^
^^ The Orions have discovered Stellar Cartography and have joined the quadrant's
^^ effort to produce a unified map of all known space. But they are holding something
^^ back from the others. Orion raiding expeditions make the other races' deep space
^^ exploration programs sound like a joke. They must be something that they discovered
^^ on one of their raids that is of immense importance.....
^
^^ We must spare no effort to get the Orions to share their star maps with us.
^
ENDTEXT
JUSTONCE
@ENDIF

@IF
TURN
turn=250
@THEN
TEXT
CHAPTER SIX - Message from the Delta Quadrant
^
^^ We intercepted a message from a Federation Vessel that was presumed to be lost,
^^ USS Voyager. They have been marooned in the Delta Quadrant and have had some
^^ contact with the BORG there. As far as we can tell, the BORG are embroiled in a
^^ losing battle with a power from another dimension, know only as SPECIES 8472.
^^ Our strategists predict that the BORG presence in our sector will diminish.
^
^^ We should make use of this golden opportunity to attack......
^
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Cube
attacker=ANYBODY
defender=Borg
@THEN
TEXT
CHAPTER SEVEN - The Turning of the Tide
^
^^ With the destruction of the first BORG cube, the collective senses that its
^^ intial assessment of the inherent weaknesses of the species in Quadrant Alpha
^^ was inadequate. The Borg Home World sends a reinforcement cube through a
^^ transwarp conduit to Unimatrix 01........
^
ENDTEXT
CREATEUNIT
unit=Cube
owner=TRIGGERDEFENDER
veteran=yes
homecity=none
locations
53,63
54,64
53,65
52,64
endlocations
JUSTONCE
@ENDIF

@IF
CITYTAKEN
city=unimatrix 01
attacker=ANYBODY
defender=Borg
@THEN
TEXT
CHAPTER NINE - the Fall of Unimatrix 01
^
^^ The quadrant breathes a sigh of relief but......analysis of data modules at
^^ Unimatrix 01 reveals that the BORG Queen has already relocated to Unimatrix 00.
^^ The BORG have been dealt a severe blow but are far from defeat.
^
^^ Portions of modified Romulan Sunseed programing code were discovered. The
^^ few ion storms that were encountered earlier were merely the result of secret
^^ testing by the Tal'Shair that even the preator was not aware of. In response to
^^ our Genesis Research, the BORG have adopted Sunseed as a new weapons program.
^^ The BORG Sunseed program has already passed the test phase. We must quickly
^^ muster an armada of starships (including scouts and probes) to dissipate the
^^ growing ion storm front and destroy the control centre, located in a derelict
^^ orbiting the source of the storms. If we do not stop the storms soon, space
^^ travel will cease and all species will slowly revert into pre-warp cultures.
^
ENDTEXT
CREATEUNIT
unit=Derelict
owner=Borg
veteran=no
homecity=none
locations
42,12
endlocations
JUSTONCE
CHANGETERRAIN
terraintype=10
maprect
43,3,47,3,47,11,43,11
@ENDIF

@IF
UNITKILLED
unit=Derelict
attacker=ANYBODY
defender=Borg
@THEN
TEXT
CHAPTER TEN - Death of a Star : End of an Invasion
^
^^ The BORG Sunseed controller has been destroyed, all that is left of
^^ the seeding star is a dead core. All ion storm activity should cease
^^ soon and the quadrant is safe once again.
^
ENDTEXT
CHANGETERRAIN
terraintype=1
maprect
44,10,44,10,44,10,44,10
@ENDIF

@IF
CITYTAKEN
city=Unimatrix 00
attacker=ANYBODY
defender=BORG
@THEN
TEXT
EPILOGUE - the Queen is Dead, Long Live the Queen.
^
^^ As troops pour into Unimatrix 00, the BORG Queen is captured after
^^ some effort. She is kept in a zoo on Nimbus III and it is said that she
^^ is a major attraction there.
^
^^ The first stable wormhole leading to the Gamma quadrant has revealed
^^ the existance of yet another group of nasties, called the DOMINION.
^^ Intelligence believes that they are massing for an invasion.
^  But then, that is another story.............
^^
^  Kobayashi thanks you for playing
^
^^ STAR TREK : BATTLE for the ALPHA QUADRANT
^
ENDTEXT
JUSTONCE
@ENDIF

@IF
TURN
turn=5
@THEN
GIVETECHNOLOGY
receiver=Borg
technology=50
@ENDIF

@IF
TURN
turn=5
@THEN
GIVETECHNOLOGY
receiver=Borg
technology=81
@ENDIF

@IF
TURN
turn=5
@THEN
GIVETECHNOLOGY
receiver=Borg
technology=33
@ENDIF

@IF
CITYTAKEN
city=unimatrix 02
attacker=ANYBODY
defender=Borg
@THEN
CREATEUNIT
unit=Cube
owner=TRIGGERDEFENDER
veteran=yes
homecity=none
locations
47,1
44,0
50,0
endlocations
@ENDIF

@IF
CITYTAKEN
city=unimatrix 03
attacker=ANYBODY
defender=Borg
@THEN
CREATEUNIT
unit=Cube
owner=TRIGGERDEFENDER
veteran=yes
homecity=none
locations
47,1
50,0
44,0
endlocations
@ENDIF

@IF
RANDOMTURN
denominator=100
@THEN
TEXT
^
Our Astrophysics department detects that an Ion Storm has just formed. What could be causing
these storms?
^
ENDTEXT
CREATEUNIT
unit=Ion Storm
owner=borg
veteran=no
homecity=none
locations
10,80
12,74
endlocations
JUSTONCE
@ENDIF

@IF
RANDOMTURN
denominator=100
@THEN
TEXT
^
Our Astrophysics department detects that an Ion Storm has just formed. Units are advised to be
on the lookout as these storms can be very destructive.
^
ENDTEXT
CREATEUNIT
unit=Ion Storm
owner=borg
veteran=no
homecity=none
locations
99,95
124,46
endlocations
JUSTONCE
@ENDIF

@IF
RANDOMTURN
denominator=100
@THEN
TEXT
^
Our Astrophysics department detects that an Ion Storm has just formed. Various parties throughout
the quadrant begin to voice their concerns over what the source of these storms could be.
^
ENDTEXT
CREATEUNIT
unit=Ion Storm
owner=borg
veteran=no
homecity=none
locations
126,40
107,91
endlocations
JUSTONCE
HASTRIGGERED
@ENDIF

@IF
RANDOMTURN
denominator=200
@THEN
TEXT
^
The Astrophysics department detects yet another Ion Storm forming. Could they be a side-effect of
space travel?
^
ENDTEXT
CREATEUNIT
unit=Ion Storm
owner=borg
veteran=no
homecity=none
locations
12,74
10,80
endlocations
JUSTONCE
@ENDIF

@IF
RANDOMTURN
denominator=200
@THEN
TEXT
^
Yet another Ion Storm has just formed and there are no signs that this is a temporary phenomenon.
We must try to discover the source of these storms. Perhaps we can use them against the other races.
^
ENDTEXT
CREATEUNIT
unit=Ion Storm
owner=borg
veteran=no
homecity=none
locations
124,46
99,95
endlocations
JUSTONCE
@ENDIF

@IF
RANDOMTURN
denominator=200
@THEN
TEXT
^
Yet another Ion Storm has just formed. Intelligence points out that BORG vessels seem to have a
form of shielding that is 100% effective against these storms. If these storms continue to
increase in frequency, the quadrant's races will be at a severe disadvantage.
^
ENDTEXT
CREATEUNIT
unit=Ion Storm
owner=borg
veteran=no
homecity=none
locations
107,91
126,40
endlocations
JUSTONCE
HASTRIGGERED
@ENDIF

@IF
UNITKILLED
unit=Genesis Torp
attacker=ANYBODY
defender=ANYBODY
@THEN
TEXT
^
^^ A Genesis Torpedo has undergone an uncontrolled detonation. The resulting
^^ implosion has forced the Genesis Wave into Null-space and may reappear at
^^ anytime and anyplace. Are we toying with knowledge that was only meant to
^^ be known to the gods?
^
ENDTEXT
CREATEUNIT
unit=Ion Storm
owner=borg
veteran=no
homecity=none
locations
126,78
62,50
endlocations
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=10
receiver=Federation
@THEN
TEXT
MINOR INTERLUDE
^
^ Starfleet Cadet James T. Kirk beats the 'No Win Scenario' and rescues
^ the Kobayashi Maru. He receives a commendation for original thinking. 
^ Kirk goes on to captain the U.S.S. Enterprise and becomes a legend and 
^ role-model in his time and beyond.
^
^ note1- This message is not related to the Kobayashi No Win Option
^ note2- You will not be commended for engaging cheating mode
^
ENDTEXT
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=29
receiver=Romulans
@THEN
TEXT
MINOR INTERLUDE
^
^ The Romulan Star Empire develops the first CLOAKING DEVICE. This 
^ pivotal discovery will eventually encourage a myriad of the Romulan  
^ intelligence agencies to merge into the all powerful TAL'SHAIR.
^
^ As for the non-Roumlans races out there, only a species so preoccupied
^ with the clandestine and covert, would conceive of a device that bends
^ light and masks emissions. Sorry. (Klingons will eventually copy the  
^ device design but they will use it mainly for tactical purposes)
^
ENDTEXT
JUSTONCE
@ENDIF

@IF
RECEIVEDTECHNOLOGY
technology=20
receiver=Klingons
@THEN
TEXT
MINOR INTERLUDE
^
^ The Imperial Klingon Empire develops the first MIND-SIFTER. This invention
^ will allow the comprehensive screening of candidates that will eventually  
^ make it possible for the Klingons to introduce the KLINGON WAR ACADEMY.
^
^ As for the non-Klingon races out there, only a belligerent and barbaric 
^ race like the Klingons would condone the widespread violation of something 
^ as private as the mind. So no mind-sifter for you.
^
ENDTEXT
JUSTONCE
@ENDIF

@IF
TURN
turn=450
@THEN
TEXT
^
^There are 50 years (200 turns) before the scenario ends.
^
ENDTEXT
@ENDIF

@IF
TURN
turn=550
@THEN
TEXT
^
^ There are only 25 years(100 turns) before the scenario ends.
^ If you are going to do anything that will improve your score, 
^ you should do it now.
^
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Defiant
attacker=ANYBODY
defender=Federation
@THEN
TEXT
^
^^ The Defiant is presumed lost, with all hands onboard including Sisko,
^^ Kira, O'brien, Dax and all the gang.
^
^^ Historian's note: In DS9, the Defiant was destoyed in a Breen attack.
^
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=Kahless' Sword
attacker=ANYBODY
defender=Klingons
@THEN
TEXT
^^
^^ The Sword of Kahless is lost....Again
^^ Will we have to wait another millenia before it returns?
^^
ENDTEXT
@ENDIF

@IF
UNITKILLED
unit=D'deridex
attacker=Borg
defender=Romulans
@THEN
TEXT
^
^ A Romulan D'deridex class warbird has just been lost to the BORG.
^ The Tal'Shair operative onboard only managed to send a single message
^ through massive subspace jamming before the ship was assimilated. The
^ garbled message contained only one discernable word..........
^
^^ ....... SUNSEED
^
ENDTEXT
JUSTONCE
@ENDIF

@ENDEVENTS
